* Wealth index calculation. Trevor Croft, 05/08/2017. Liberia MIS 2016.
cd 'C:\Projects\Analysis\Wealth Index Construction\LBMIS2016\Wealth'.

* Added in to check the sample - looks like the sample points are mis-classified.
*GET DATA /TYPE=XLSX
  /FILE='LBMIS_sample.xlsx'
  /SHEET=name 'LBMIS_sample'
  /CELLRANGE=full
  /READNAMES=on
  /ASSUMEDSTRWIDTH=32767.
*EXECUTE.
*DELETE VARIABLES countyname residence.
*dataset name sample.

include file='wealth_assets.sps'.
missing values QH113 (99.9).
execute.
set tvars=both.

* Name the dataset window for the HH data for use later.
dataset name assets.
save outfile='assets.sav'.

* Used for checking sample.
*match files file=* table='sample' rename cluster=qhclust /by qhclust.
*execute.

* Replace the sample info.
*compute QHREGION = Region.
*compute QHCOUNTY = County.
*compute QHTYPE = Urbrur - 1.
*if (Urbrur = 1) QHTYPE = 1.


* Macro definitions to perform some recoding automatically.
* Note: Do not use an asterisk in front of a macro name to try to comment it out - it will run any way because of the way the macros are expanded.
* Delete the line instead or change the spelling of the macro in the comment.
* Do not use the names of macros in comments - they will also be expanded too, and likely will fail.

*{Create binary variables based on condition and give label }.
define dichotomize( !positional !enclose('(',')') / !positional !tokens(1) / !positional !tokens(1) )
compute !2=0.
if (!1) !2=1.
variable labels !2 !3.
value labels !2 0 'No' 1 'Yes'.
formats !2 (f1.0).
!enddefine.

*(Separate shared toilets from non-shared toilets).
define shared_fac( !positional !tokens(1) / !positional !tokens(1) / !positional !tokens(1) ).
compute !2 = 0.
do if (QH106=1).
+ if (!1=1) !2 = 1.
+ compute !1 = 0.
end if.
variable labels !2 !3.
value labels !2 0 'No' 1 'Yes'.
formats !2 (f1.0).
!enddefine.

*{Reset missing values to 'does not have', change 2 code to 0}.
define no2zero( !positional !tokens(1) )
if (missing(!1) | !1<>1) !1=0.
value labels !1 0 'No' 1 'Yes'.
!enddefine.

*{Construct Variables}.

* Source of drinking water.
dichotomize (QH101=11) QH101_11 "Source of drinking water: Piped - into dwelling".
dichotomize (QH101=12) QH101_12 "Source of drinking water: Piped - to yard/plot".
dichotomize (QH101=13) QH101_13 "Source of drinking water: Piped - to neighbor".
dichotomize (QH101=14) QH101_14 "Source of drinking water: Piped - public tap / Standpipe".
dichotomize (QH101=21) QH101_21 "Source of drinking water: Hand pump / Tube well or borehole".
dichotomize (QH101=31) QH101_31 "Source of drinking water: Dug well - protected".
dichotomize (QH101=32) QH101_32 "Source of drinking water: Dug well - unprotected".
dichotomize (QH101=41) QH101_41 "Source of drinking water: Spring - protected".
dichotomize (QH101=42) QH101_42 "Source of drinking water: Spring - unprotected".
*ichotomize (QH101=51) QH101_51 "Source of drinking water: Rainwater".
dichotomize (QH101=61 or QH101=71) QH101_61 "Source of drinking water: Tanker truck or Cart with small truck".
*ichotomize (QH101=71) QH101_71 "Source of drinking water: Cart with small tank".
dichotomize (QH101=81) QH101_81 "Source of drinking water: Surface water (river/dam/lake/pond/stream/canal/irrigation channel)".
dichotomize (QH101=91) QH101_91 "Source of drinking water: Bottled water".
dichotomize (QH101=92) QH101_92 "Source of drinking water: Mineral water in sachet".
dichotomize (QH101=51 or QH101=96) QH101_96 "Source of drinking water: Other or Rainwater".


* Type of toilet facility.
dichotomize (QH105=11) QH105_11 "Type of toilet facility: Flush - to piped sewer system".
dichotomize (QH105=12) QH105_12 "Type of toilet facility: Flush - to septic tank".
dichotomize (QH105=13) QH105_13 "Type of toilet facility: Flush - to pit latrine".
dichotomize (QH105=14 or QH105 = 15) QH105_14 "Type of toilet facility: Flush - to somewhere else".
*ichotomize (QH105=15) QH105_15 "Type of toilet facility: Flush - don't know where".
dichotomize (QH105=21) QH105_21 "Type of toilet facility: Pit latrine - ventilated improved pit (VIP)".
dichotomize (QH105=22) QH105_22 "Type of toilet facility: Pit latrine - with slab".
dichotomize (QH105=23) QH105_23 "Type of toilet facility: Pit latrine - without slab / open pit".
dichotomize (QH105=31) QH105_31 "Type of toilet facility: Composting toilet".
dichotomize (QH105=41) QH105_41 "Type of toilet facility: Bucket toilet".
dichotomize (QH105=51) QH105_51 "Type of toilet facility: Hanging toilet/hanging latrine".
dichotomize (QH105=61) QH105_61 "Type of toilet facility: No facility / bush / field".
dichotomize (QH105=96) QH105_96 "Type of toilet facility: Other".

shared_fac QH105_11 QH105_11_sh "Type of toilet facility: Flush - to piped sewer system - shared".
shared_fac QH105_12 QH105_12_sh "Type of toilet facility: Flush - to septic tank - shared".
shared_fac QH105_13 QH105_13_sh "Type of toilet facility: Flush - to pit latrine - shared".
shared_fac QH105_14 QH105_14_sh "Type of toilet facility: Flush - to somewhere else - shared".
*hared_fac QH105_15 QH105_15_sh "Type of toilet facility: Flush - don't know where - shared".
shared_fac QH105_21 QH105_21_sh "Type of toilet facility: Pit latrine - ventilated improved pit (VIP) - shared".
shared_fac QH105_22 QH105_22_sh "Type of toilet facility: Pit latrine - with slab - shared".
shared_fac QH105_23 QH105_23_sh "Type of toilet facility: Pit latrine - without slab / open pit - shared".
shared_fac QH105_31 QH105_31_sh "Type of toilet facility: Composting toilet - shared".
*hared_fac QH105_41 QH105_41_sh "Type of toilet facility: Bucket toilet - shared".
shared_fac QH105_51 QH105_51_sh "Type of toilet facility: Hanging toilet/hanging latrine - shared".
shared_fac QH105_96 QH105_96_sh "Type of toilet facility: Other - shared".


* Type of cooking fuel.
dichotomize (QH108=1) QH108_1 "Type of cooking fuel: Electricity".
dichotomize (QH108=2) QH108_2 "Type of cooking fuel: Gas cylinder".
dichotomize (QH108=3) QH108_3 "Type of cooking fuel: Kerosene stove".
dichotomize (QH108=4) QH108_4 "Type of cooking fuel: Fire coal / Charcoal".
dichotomize (QH108=5) QH108_5 "Type of cooking fuel: Wood".
dichotomize (QH108=95) QH108_95 "Type of cooking fuel: No food cooked in HH".
dichotomize (QH108=96) QH108_96 "Type of cooking fuel: Other".

* regrouped Cows / Bulls.
* Cows / Bulls. 
if (missing(QH111A) | QH110 <> 1) QH111A=0.
missing values QH111A (99).
compute QH111A_1 = (QH111A >= 1 & QH111A <= 98).
*compute QH111A_2 = (QH111A >= 5 & QH111A <= 9).
*compute QH111A_3 = (QH111A >= 10 & QH111A <= 98).
*variable labels QH111A_1 'Cows / Bulls: 1-4' /QH111A_2 'Cows / Bulls: 5-9' /QH111A_3 'Cows / Bulls: 10+'.
variable labels QH111A_1 'Cows / Bulls: 1+'.

* Pigs.
if (missing(QH111B) | QH110 <> 1) QH111B=0.
missing values QH111B (99).
compute QH111B_1 = (QH111B >= 1 & QH111B <= 4).
compute QH111B_2 = (QH111B >= 5 & QH111B <= 9).
compute QH111B_3 = (QH111B >= 10 & QH111B <= 98).
variable labels QH111B_1 'Pigs: 1-4' /QH111B_2 'Pigs: 5-9' /QH111B_3 'Pigs: 10+'.


* Goats.
if (missing(QH111C) | QH110 <> 1) QH111C=0.
missing values QH111C (99).
compute QH111C_1 = (QH111C >= 1 & QH111C <= 4).
compute QH111C_2 = (QH111C >= 5 & QH111C <= 9).
compute QH111C_3 = (QH111C >= 10 & QH111C <= 98).
variable labels QH111C_1 'Goats: 1-4' /QH111C_2 'Goats: 5-9' /QH111C_3 'Goats: 10+'.


* Sheep.
if (missing(QH111D) | QH110 <> 1) QH111D=0.
missing values QH111D (99).
compute QH111D_1 = (QH111D >= 1 & QH111D <= 4).
compute QH111D_2 = (QH111D >= 5 & QH111D <= 9).
compute QH111D_3 = (QH111D >= 10 & QH111D <= 98).
variable labels QH111D_1 'Sheep: 1-4' /QH111D_2 'Sheep: 5-9' /QH111D_3 'Sheep: 10+'.


* Chickens / Poultry.
if (missing(QH111E) | QH110 <> 1) QH111E=0.
missing values QH111E (99).
compute QH111E_1 = (QH111E >= 1 & QH111E <= 9).
compute QH111E_2 = (QH111E >= 10 & QH111E <= 29).
compute QH111E_3 = (QH111E >= 30 & QH111E <= 98).
variable labels QH111E_1 'Chickens / Poultry: 1-9' /QH111E_2 'Chickens / Poultry: 10-29' /QH111E_3 'Chickens / Poultry: 30+'.


* Hectares for agricultural land.
compute landarea = QH113.
if (missing(QH113) | QH113 >= 99.8) landarea = 99.9.
if (missing(QH112) | QH112 <> 1) landarea=0.
missing values landarea (99.9).

* Electricity.
no2zero QH114A.
* Generator.
no2zero QH114B.
* Radio.
no2zero QH114C.
* Mobile telephone.
no2zero QH114D.
* Ice box ( refridgerator ).
no2zero QH114E.
* Table.
no2zero QH114F.
* Chairs.
no2zero QH114G.
* Cupboard.
no2zero QH114H.
* Mattress.
no2zero QH114I.
* Sewing machine.
no2zero QH114J.
* Television.
no2zero QH114K.
* Computer.
no2zero QH114L.
* Bench or stool.
no2zero QH114M.
* Watch.
no2zero QH115A.
* Bicycle.
no2zero QH115B.
* Motorcycle / Scooter.
no2zero QH115C.
* Car / Truck.
no2zero QH115D.
* Boat / Canoe.
no2zero QH115E.
* Bank account.
no2zero QH116.

* Main floor material.
dichotomize (QH131=11) QH131_11 "Main floor material: Earth / Sand / Mud".
dichotomize (QH131=21) QH131_21 "Main floor material: Wood planks".
dichotomize (QH131=31) QH131_31 "Main floor material: Parquet or polished wood".
dichotomize (QH131=32) QH131_32 "Main floor material: Floor mat, linoleum, vinyl".
dichotomize (QH131=33) QH131_33 "Main floor material: Ceramic tiles / Terrazo".
dichotomize (QH131=34) QH131_34 "Main floor material: Concrete, cement".
dichotomize (QH131=35) QH131_35 "Main floor material: Carpet".
*ichotomize (QH131=96) QH131_96 "Main floor material: Other".


* Main roof material.
dichotomize (QH132=12) QH132_12 "Main roof material: Thatch / Palm leaf".
*ichotomize (QH132=21) QH132_21 "Main roof material: Rustic mat".
dichotomize (QH132=21 or QH132=22 or QH132=23) QH132_22 "Main roof material: Palm / Bamboo or Rustic mat".
*ichotomize (QH132=23) QH132_23 "Main roof material: Wood planks".
dichotomize (QH132=24) QH132_24 "Main roof material: Tarpaulin, plastic".
dichotomize (QH132=31) QH132_31 "Main roof material: Zinc, metal, aluminum".
dichotomize (QH132=32) QH132_32 "Main roof material: Wood".
dichotomize (QH132=34) QH132_34 "Main roof material: Ceramic tiles".
dichotomize (QH132=35) QH132_35 "Main roof material: Concrete, cement".
dichotomize (QH132=36) QH132_36 "Main roof material: Asbestos sheets / Shingles".
*ichotomize (QH132=96) QH132_96 "Main roof material: Other".


* Main wall material.
dichotomize (QH133=11) QH133_11 "Main wall material: Mud and sticks".
dichotomize (QH133=12) QH133_12 "Main wall material: Cane / Palm / Trunks".
dichotomize (QH133=13) QH133_13 "Main wall material: Straw / Thatch mats".
dichotomize (QH133=21) QH133_21 "Main wall material: Mud bricks".
dichotomize (QH133=22) QH133_22 "Main wall material: Plywood".
*ichotomize (QH133=23) QH133_23 "Main wall material: Cardboard / Plastic".
*ichotomize (QH133=24) QH133_24 "Main wall material: Reused wood".
dichotomize (QH133=31) QH133_31 "Main wall material: Zinc / Metal".
dichotomize (QH133=32) QH133_32 "Main wall material: Cement".
dichotomize (QH133=33) QH133_33 "Main wall material: Stone blocks".
dichotomize (QH133=34) QH133_34 "Main wall material: Bricks".
dichotomize (QH133=35) QH133_35 "Main wall material: Wood planks / Shingles".
*ichotomize (QH133=96) QH133_96 "Main wall material: Other".

*{Members per sleeping room}.
if (hhusual=0) hhusual=hhslept.
if (QH109>0) memsleep=trunc(hhusual/QH109).
if (QH109=0) memsleep=hhusual.
if (missing(QH109) or QH109>=99 or memsleep>=98) memsleep=99.
variable labels memsleep 'Number of members per sleeping room'.
value labels memsleep 0 'Less than 1 per room'.
formats memsleep (f2.0).
missing values memsleep (99).

* Compute urban and rural variables coded (1/0) for filters later.
compute urban=(QHTYPE = 1).
compute rural=(QHTYPE = 2).
variable labels urban 'Urban' / rural 'Rural'.
value labels urban 1 'Urban' / rural 1 'Rural'.
formats urban rural (f1.0).

execute.

* Check on indicator variable creation.
frequencies variables=QHTYPE to domestic.

* Toilet facility by shared/not shared.
crosstabs /tables=QH105 by QH106.

crosstabs /tables=QHREGION by QHTYPE.

frequencies variables=
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_61 QH101_81 QH101_91 QH101_92 QH101_96
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 QH105_96
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_95 QH108_96
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH115A QH115B QH115C QH115D QH115E QH116
  QH131_11 QH131_21 QH131_31 QH131_32 QH131_33 QH131_34 QH131_35 
  QH132_12 QH132_22 QH132_24 QH132_31 QH132_32 QH132_34 QH132_35 QH132_36 
  QH133_11 QH133_12 QH133_13 QH133_21 QH133_22 QH133_31 QH133_32 QH133_33 QH133_34 QH133_35 
  LAND memsleep
  QH111A_1 QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 landarea
.

* Turn off weights before all factor analysis.
weight off.

save outfile='assets.sav'.

*** Test Factor Analysis.
filter off.
execute.

factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_61 QH101_81 QH101_91 QH101_92 QH101_96
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 QH105_96
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_95 QH108_96
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH115A QH115B QH115C QH115D QH115E QH116
  QH131_11 QH131_21 QH131_31 QH131_32 QH131_33 QH131_34 QH131_35 
  QH132_12 QH132_22 QH132_24 QH132_31 QH132_32 QH132_34 QH132_35 QH132_36 
  QH133_11 QH133_12 QH133_13 QH133_21 QH133_22 QH133_31 QH133_32 QH133_33 QH133_34 QH133_35 
  LAND memsleep
  QH111A_1 QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 landarea
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_61 QH101_81 QH101_91 QH101_92 QH101_96
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 QH105_96
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_95 QH108_96
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH115A QH115B QH115C QH115D QH115E QH116
  QH131_11 QH131_21 QH131_31 QH131_32 QH131_33 QH131_34 QH131_35 
  QH132_12 QH132_22 QH132_24 QH132_31 QH132_32 QH132_34 QH132_35 QH132_36 
  QH133_11 QH133_12 QH133_13 QH133_21 QH133_22 QH133_31 QH133_32 QH133_33 QH133_34 QH133_35 
  LAND memsleep
  QH111A_1 QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 landarea
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /method=correlation.

*** Common Factor analysis ***.
** Removed area-specific variables **.
** Agricultural animal variables excluded
** Land area excluded
** Any others ?.

*** Common Factor Analysis.
filter off.
execute.

factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_61 QH101_81 QH101_91 QH101_92 QH101_96
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 QH105_96
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_95 QH108_96
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH115A QH115B QH115C QH115D QH115E QH116
  QH131_11 QH131_21 QH131_31 QH131_32 QH131_33 QH131_34 QH131_35 
  QH132_12 QH132_22 QH132_24 QH132_31 QH132_32 QH132_34 QH132_35 QH132_36 
  QH133_11 QH133_12 QH133_13 QH133_21 QH133_22 QH133_31 QH133_32 QH133_33 QH133_34 QH133_35 
  LAND memsleep
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_61 QH101_81 QH101_91 QH101_92 QH101_96
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 QH105_96
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_95 QH108_96
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH115A QH115B QH115C QH115D QH115E QH116
  QH131_11 QH131_21 QH131_31 QH131_32 QH131_33 QH131_34 QH131_35 
  QH132_12 QH132_22 QH132_24 QH132_31 QH132_32 QH132_34 QH132_35 QH132_36 
  QH133_11 QH133_12 QH133_13 QH133_21 QH133_22 QH133_31 QH133_32 QH133_33 QH133_34 QH133_35 
  LAND memsleep
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /save reg(ALL com)
  /method=correlation.

*** Urban Factor Analysis.
filter off.
filter by urban.
execute.

* Dropped QH101_96 QH105_31.
factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_61 QH101_81 QH101_91 QH101_92 
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_21 QH105_22 QH105_23 /*QH105_31*/ QH105_41 QH105_51 QH105_61 QH105_96
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_95 QH108_96
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH115A QH115B QH115C QH115D QH115E QH116
  QH131_11 QH131_21 QH131_31 QH131_32 QH131_33 QH131_34 QH131_35 
  QH132_12 QH132_22 QH132_24 QH132_31 QH132_32 QH132_34 QH132_35 QH132_36 
  QH133_11 QH133_12 QH133_13 QH133_21 QH133_22 QH133_31 QH133_32 QH133_33 QH133_34 QH133_35 
  LAND memsleep
  QH111A_1 QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 landarea
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_61 QH101_81 QH101_91 QH101_92 
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_21 QH105_22 QH105_23 /*QH105_31*/ QH105_41 QH105_51 QH105_61 
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_95 
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH115A QH115B QH115C QH115D QH115E QH116
  QH131_11 QH131_21 QH131_31 QH131_32 QH131_33 QH131_34 QH131_35 
  QH132_12 QH132_22 QH132_24 QH132_31 QH132_32 QH132_34 QH132_35 QH132_36 
  QH133_11 QH133_12 QH133_13 QH133_21 QH133_22 QH133_31 QH133_32 QH133_33 QH133_34 QH133_35 
  LAND memsleep
  QH111A_1 QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 landarea
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /save reg(ALL urb)
  /method=correlation.

*** Rural Factor Analysis.
filter off.
filter by rural.
execute.

* Dropped QH101_11 QH101_61 QH105_11_sh QH108_2 QH108_96 QH131_31 QH132_32 QH132_34 QH133_35.
factor /variables
  QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_81 QH101_91 QH101_92 QH101_96
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 QH105_96
  QH105_12_sh QH105_13_sh QH105_14_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_3 QH108_4 QH108_5 QH108_95 
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH115A QH115B QH115C QH115D QH115E QH116
  QH131_11 QH131_21 QH131_32 QH131_33 QH131_34 QH131_35 
  QH132_12 QH132_22 QH132_24 QH132_31 QH132_35 QH132_36 
  QH133_11 QH133_12 QH133_13 QH133_21 QH133_22 QH133_31 QH133_32 QH133_33 QH133_34 
  LAND memsleep
  QH111A_1 QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 landarea
  /missing meansub
  /analysis
  QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_81 QH101_91 QH101_92 QH101_96
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 QH105_96
  QH105_12_sh QH105_13_sh QH105_14_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_3 QH108_4 QH108_5 QH108_95 
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH115A QH115B QH115C QH115D QH115E QH116
  QH131_11 QH131_21 QH131_32 QH131_33 QH131_34 QH131_35 
  QH132_12 QH132_22 QH132_24 QH132_31 QH132_35 QH132_36 
  QH133_11 QH133_12 QH133_13 QH133_21 QH133_22 QH133_31 QH133_32 QH133_33 QH133_34
  LAND memsleep
  QH111A_1 QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 landarea
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /save reg(ALL rur)
  /method=correlation.

* Label the created score variables.
rename variables (com1 urb1 rur1=comscore urbscore rurscore).
variable labels comscore 'Common wealth score' /urbscore 'Urban wealth score' /rurscore 'Rural wealth score'.

* Add a variable used for linking later.
filter off.
string rowtype_ (A8).
compute rowtype_ = 'EST'.

* Calculate regressions.
** Area=urban.
filter off.
filter by urban.
execute.

* Declare a dataset to be written to in the regression.
dataset declare urbancorv.
* Run regression of comscore with urbscore.
regression
  /missing listwise
  /statistics coeff outs R anova
  /criteria=pin(.05) pout(.10)
  /noorigin
  /dependent comscore
  /method=enter urbscore
  /outfile=corv(urbancorv).

* Activate file of output from regression.
dataset activate urbancorv.
* Drop all rows of output except the coefficients.
select if (rowtype_ = 'EST').
execute.
* Delete unnecessary variables before merging.
delete variables DEPVAR_ VARNAME_.
* Rename variables containing the constant and the coefficient.
rename variables CONST_=urbconst urbscore=urbcoeff.

* Re-activate the main household data.
dataset activate assets.
* merge the coefficients.
match files /file = *
  /table = urbancorv
  /by ROWTYPE_.
execute.

* Calculate regressions.
** Area=rural.
filter off.
filter by rural.
execute.

* Declare a dataset to be written to in the regression.
dataset declare ruralcorv.
* Run regression of comscore with rurscore.
regression
  /missing listwise
  /statistics coeff outs R anova
  /criteria=pin(.05) pout(.10)
  /noorigin
  /dependent comscore
  /method=enter rurscore
  /outfile=corv(ruralcorv).

* Activate file of output from regression.
dataset activate ruralcorv.
* Drop all rows of output except the coefficients.
select if (rowtype_ = 'EST').
execute.
* Delete unnecessary variables before merging.
delete variables DEPVAR_ VARNAME_.
* Rename variables containing the constant and the coefficient.
rename variables CONST_=rurconst rurscore=rurcoeff.

* Re-activate the main household data.
dataset activate assets.
* merge the coefficients.
match files /file = *
  /table = ruralcorv
  /by ROWTYPE_.
execute.

dataset close urbancorv.
dataset close ruralcorv.
dataset activate assets.
filter off.

*** Calculate combined wealth score from Urban and Rural Scores.
* Use coefficients from urban and rural regressions above.
compute combscor=0.
print formats combscor (f11.5).
write formats combscor (f11.5).
** Urban.
if (urban = 1) combscor=urbconst+urbcoeff*urbscore.
** Rural.
if (rural = 1) combscor=rurconst+rurcoeff*rurscore.
variable labels combscor 'Combined national wealth score'.
execute.

compute hhwt = QHWEIGHT/1000000.
variable labels hhwt 'HH weights'.
formats hhwt (f12.6).
weight by hhwt.

filter off.
execute.

frequencies variables=combscor comscore
  /format=notable
  /ntiles=5
  /statistics=minimum maximum stddev mean
  /histogram normal
  /order=analysis.

filter off.
filter by urban.
execute.

frequencies variables=combscor urbscore
  /format=notable
  /ntiles=5
  /statistics=minimum maximum stddev mean
  /histogram normal
  /order=analysis.

filter off.
filter by rural.
execute.

frequencies variables=combscor rurscore
  /format=notable
  /ntiles=5
  /statistics=minimum maximum stddev mean
  /histogram normal
  /order=analysis.

filter off.
execute.

*Calculate quintiles and scores for data file.
compute hhmemwt=QHWEIGHT*hhusual/1000000.
variable labels hhmemwt 'HH members weighting for index'.
formats hhmemwt (f12.6).
weight by hhmemwt.

filter off.
filter by urban.
execute.

rank variables=urbscore (A) /rank /ntiles (5) /print=yes /ties=mean.

filter off.
filter by rural.
execute.

rank variables=rurscore (A) /rank /ntiles (5) /print=yes /ties=mean.

filter off.
execute.

rank variables=combscor (A) /rank /ntiles (5) /print=yes /ties=mean.

variable labels ncombsco 'Combined wealth index' /nurbscor 'Urban wealth index' /nrurscor 'Rural wealth index'.
value labels ncombsco nurbscor nrurscor 1 'Lowest' 2 'Second' 3 'Middle' 4 'Fourth' 5 'Highest'.

*** Check on quintiles.
frequencies variables=ncombsco nurbscor nrurscor.

weight by hhwt.

ctables /table (
  QH101_11+QH101_12+QH101_13+QH101_14+QH101_21+QH101_31+QH101_32+QH101_41+QH101_42+QH101_61+QH101_81+QH101_91+QH101_92+QH101_96+
  QH105_11+QH105_12+QH105_13+QH105_14+QH105_21+QH105_22+QH105_23+QH105_31+QH105_41+QH105_51+QH105_61+QH105_96+
  QH105_11_sh+QH105_12_sh+QH105_13_sh+QH105_14_sh+QH105_21_sh+QH105_22_sh+QH105_23_sh+QH105_31_sh+QH105_51_sh+QH105_96_sh+
  QH108_1+QH108_2+QH108_3+QH108_4+QH108_5+QH108_95+QH108_96+
  QH114A+QH114B+QH114C+QH114D+QH114E+QH114F+QH114G+QH114H+QH114I+QH114J+QH114K+QH114L+QH114M+QH115A+QH115B+QH115C+QH115D+QH115E+QH116+
  QH131_11+QH131_21+QH131_31+QH131_32+QH131_33+QH131_34+QH131_35+
  QH132_12+QH132_22+QH132_24+QH132_31+QH132_32+QH132_34+QH132_35+QH132_36+
  QH133_11+QH133_12+QH133_13+QH133_21+QH133_22+QH133_31+QH133_32+QH133_33+QH133_34+QH133_35+
  LAND+memsleep+
  QH111A_1+QH111B_1+QH111B_2+QH111B_3+
  QH111C_1+QH111C_2+QH111C_3+QH111D_1+QH111D_2+QH111D_3+
  QH111E_1+QH111E_2+QH111E_3+landarea
  )[S][Mean F8.3] by (ncombsco+nurbscor+nrurscor)[C]
  /slabels visible=no.

* Alternative instead of ctables.
*means tables=
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_61 QH101_81 QH101_91 QH101_92 QH101_96
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 QH105_96
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_95 QH108_96
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH115A QH115B QH115C QH115D QH115E QH116
  QH131_11 QH131_21 QH131_31 QH131_32 QH131_33 QH131_34 QH131_35 
  QH132_12 QH132_22 QH132_24 QH132_31 QH132_32 QH132_34 QH132_35 QH132_36 
  QH133_11 QH133_12 QH133_13 QH133_21 QH133_22 QH133_31 QH133_32 QH133_33 QH133_34 QH133_35 
  LAND memsleep
  QH111A_1 QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 landarea
    by ncombsco nurbscor nrurscor
  /cells mean count stddev.

graph /histogram(normal)=combscor /title= 'Distribution of Households by Wealth Scores'.
frequencies variables=combscor
  /format=notable
  /ntiles=5
  /statistics=stddev minimum maximum semean mean median mode skewness seskew kurtosis sekurt
  /order=analysis.

weight off.
filter off.
write formats combscor urbscore rurscore (f11.5).

* Save final dataset of assets.
save outfile='assets.sav'.

*** Write out scores file.
write outfile='scores.dat' table /QHCLUST QHNUMBER combscor ncombsco urbscore nurbscor rurscore nrurscor.
execute.

* Produce table 2.6 weighted by de jure population to test.
weight by hhmemwt.
compute total = 0.
variable labels total 'Total'.
value labels total 0 ' '.
ctables /vlabels variables=QHTYPE QHREGION total Ncombsco DISPLAY=BOTH
  /table QHTYPE [C] + QHREGION [C] + total [C] BY Ncombsco [C][ROWPCT.COUNT '' F8.1] + total [C][ROWPCT.COUNT '' F8.1, COUNT '' F8.0]
  /categories variables=Ncombsco total=yes
  /titles title='Table 2.6 Wealth Quintiles' ''
    'Percent distribution of the de jure population by wealth quintiles, according to residence and region, Liberia MIS 2016   '
  corner='Residence/region' /slabels visible=no.

weight off.